-------------------------------------------------------------------
--           RAPID - RAPID ADA PORTABLE INTERFACE DESIGNER         
--           TCL PEER FOR THE MCC GUI PACKAGE LIBRARY 
--           Copyright (C) 1999 Martin C. Carlisle.                
--                                                                 
-- RAPID is free software;  you can  redistribute it  and/or modify
-- it under terms of the  GNU General Public License as published  
-- by the Free Software  Foundation;  either version 2,  or (at your
-- option) any later version.  RAPID is distributed in the hope that 
-- it will be useful, but WITHOUT ANY WARRANTY;  without even the 
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
-- PURPOSE.  See the GNU General Public License for more details.  
-- You should have  received  a copy of the GNU General Public License
-- distributed with RAPID; see file COPYING.  If not, write to the 
-- Free Software Foundation,  59 Temple Place - Suite 330,  Boston, 
-- MA 02111-1307, USA.                                                 
--                                                                     
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an 
-- executable, this unit does not by itself cause the resulting 
-- executable to be covered by the GNU General Public License.  
-- This exception does not however invalidate any other reasons 
-- why the executable file might be covered by the GNU Public 
-- License.  This exception does not apply to executables which
-- are GUI design tools, or that could act as a replacement
-- for RAPID.
------------------------------------------------------------------------------
with Ada.Unchecked_Conversion;
package body Mcc.Gui.Widget.Text_Entry is
   Max_Text_Length : constant := 4096;
   Text : String(1..Max_Text_Length);

   -----------
   -- Clear --
   -----------

   procedure Clear (Obj  : in out Text_Entry) is
   begin
      Peer.Eval(Obj.My_Peer.Name.all & " delete 0 end");
   end Clear;

   ------------
   -- Create --
   ------------

   procedure Create
     (Obj    : in out Text_Entry;
      Parent : in     Mcc.Gui.Container.Container'Class;
      X      : in     Integer;
      Y      : in     Integer;
      Width  : in     Natural;
      Height : in     Natural)
   is
      type Parent_Access is access constant Mcc.Gui.Container.Container'Class;
      function Convert is new Ada.Unchecked_Conversion(
         Parent_Access,Mcc.Gui.Container.Container_Pointer);
   begin
      Obj.My_Peer := Peer.Create_Peer(Mcc.Gui.Container.Get_Peer(Parent));
      Peer.Eval("entry " & Obj.My_Peer.Name.all);
      Peer.Eval("place " & Obj.My_Peer.Name.all &
         " -anchor nw" &
         " -x " & Integer'Image(X) &
         " -y " & Integer'Image(Y) &
         " -width" & Integer'Image(Width) &
         " -height" & Integer'Image(Height));
      Obj.Parent := Convert(Parent'Unchecked_Access);
   end Create;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return String is
      Last : Natural;
   begin
      Peer.Eval(
         "set entry_text [ " & Obj.My_Peer.Name.all &
         " get ]");
      Peer.Get_Value(Name => "entry_text",
         Result => Text,
         Last => Last);
      return Text(Text'First..Last);
   end Get_Text;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return Integer is
   begin
      return Integer'Value(Get_Text(Obj));
   end Get_Text;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return Float is
   begin
      return Float'Value(Get_Text(Obj));
   end Get_Text;

   ---------------------
   -- Get_Text_Length --
   ---------------------

   function Get_Text_Length (Obj : in Text_Entry) return Natural is
      Result : String := Get_Text(Obj);
   begin
      return Result'Length;
   end Get_Text_Length;

   ---------------
   -- Highlight --
   ---------------

   procedure Highlight
     (Obj   : in out Text_Entry;
      Start : in     Natural;
      Stop  : in     Natural)
   is
   begin
      Peer.Eval(Obj.My_Peer.Name.all & " selection range " &
         integer'image(start) & integer'image(stop));
      Peer.Eval("focus " & Obj.My_Peer.Name.all & ascii.lf & "update");
   end Highlight;

   procedure Highlight(Obj : in out Text_Entry) is
   begin
      Peer.Eval(Obj.My_Peer.Name.all & " selection range 0 end");
      Peer.Eval("focus " & Obj.My_Peer.Name.all & ascii.lf & "update");
   end Highlight;
   
   --------------
   -- Set_Text --
   --------------

   procedure Set_Text
     (Obj  : in out Text_Entry;
      Text : in     String)
   is
   begin
      Clear(Obj);
      Peer.Eval(Obj.My_Peer.Name.all &
         " insert end """ & Peer.Fix_Quotes(Text) & """");
   end Set_Text;

   ------------------------------------------------
   -- procedure Disable
   --
   -- prevent the user from interacting with the 
   -- Text_Entry
   ------------------------------------------------
   procedure Disable(Obj : in out Text_Entry) is
   begin
      Peer.Eval(Obj.My_Peer.Name.all &
         " configure -state disabled");
   end Disable;

   procedure Enable(Obj : in out Text_Entry) is
   begin
      Peer.Eval(Obj.My_Peer.Name.all &
         " configure -state normal");
   end Enable;

   ------------------------------------------------
   -- procedure Set_Text
   --
   -- Set text for a text entry using
   -- image of integer (w/o leading spaces)
   ------------------------------------------------
   procedure Set_Text(
      Obj  : in out Text_Entry;
      Text : in     Integer) is
      -- return image of integer w/o leading space
      function integer_image(x : in integer) return String is
         result : string := integer'image(x);
      begin
         if result(result'first) = ' ' then
            return result(result'first+1..result'last);
         else
            return result;
         end if;
      end integer_image;
   begin
      Set_Text(Obj,Integer_Image(Text));
   end Set_Text;


end Mcc.Gui.Widget.Text_Entry;
