-------------------------------------------------------------------
--           RAPID - RAPID ADA PORTABLE INTERFACE DESIGNER         
--           MCC GUI PACKAGE LIBRARY - GWINDOWS PEER
--           Copyright (C) 2001 Martin C. Carlisle.                
--                                                                 
-- RAPID is free software;  you can  redistribute it  and/or modify
-- it under terms of the  GNU General Public License as published  
-- by the Free Software  Foundation;  either version 2,  or (at your
-- option) any later version.  RAPID is distributed in the hope that 
-- it will be useful, but WITHOUT ANY WARRANTY;  without even the 
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
-- PURPOSE.  See the GNU General Public License for more details.  
-- You should have  received  a copy of the GNU General Public License
-- distributed with RAPID; see file COPYING.  If not, write to the 
-- Free Software Foundation,  59 Temple Place - Suite 330,  Boston, 
-- MA 02111-1307, USA.                                                 
--                                                                     
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an 
-- executable, this unit does not by itself cause the resulting 
-- executable to be covered by the GNU General Public License.  
-- This exception does not however invalidate any other reasons 
-- why the executable file might be covered by the GNU Public 
-- License.  This exception does not apply to executables which
-- are GUI design tools, or that could act as a replacement
-- for RAPID.
------------------------------------------------------------------------------
with Peer;
use Peer;
with Peer_To_Mcc;
with Gwindows.List_Boxes;
package body Mcc.Gui.Widget.Listbox is

   ---------------
   -- Add_Entry --
   ---------------

   procedure Add_Entry
     (Obj      : in out Listbox;
      Location : in     Natural;
      Text     : in     String)
   is
   begin
      Gwindows.List_Boxes.Add (
         List  => Gwindows.List_Boxes.List_Box_Type(Obj.My_Peer.all),
         After => Location,
         Value => +Text);
   end Add_Entry;

   -----------
   -- Clear --
   -----------

   procedure Clear (Obj  : in out Listbox) is
   begin
      Gwindows.List_Boxes.Clear(
         Gwindows.List_Boxes.List_Box_Type(Obj.My_Peer.all));
   end Clear;

   -----------
   -- Count --
   -----------

   function Count (Obj : in Listbox) return Natural is
   begin
      return Gwindows.List_Boxes.Count (
         Gwindows.List_Boxes.List_Box_Type(Obj.My_Peer.all));
   end Count;

   ------------
   -- Create --
   ------------

   procedure Create
     (Obj                  : in out Listbox;
      Parent               : in     Mcc.Gui.Container.Container'Class;
      X                    : in     Integer;
      Y                    : in     Integer;
      Width                : in     Natural;
      Height               : in     Natural;
      Horizontal_Scrollbar : in     Boolean;
      Vertical_Scrollbar   : in     Boolean)
   is
      My_Peer : Gwindows.List_Boxes.List_Box_Access;
   begin
      My_Peer := new Gwindows.List_Boxes.List_Box_Type;
      Gwindows.List_Boxes.Create(
         List       => My_Peer.all,
         Parent     => Mcc.Gui.Container.Get_Peer(Parent).all,
         Left       => X,
         Top        => Y,
         Width      => Width,
         Height     => Height,
         Sort       => False);
      Obj.My_Peer := Peer.Peer(My_Peer);
      Peer_To_Mcc.Hash_Package.Set(
         K => My_Peer.all'Address,
         E => Obj'Unrestricted_Access);
   end Create;

   ------------------
   -- Delete_Entry --
   ------------------

   procedure Delete_Entry
     (Obj   : in out Listbox;
      Start : in     Natural;
      Stop  : in     Natural)
   is
   begin
      for I in reverse Start..Stop loop
         Gwindows.List_Boxes.Delete (
            List => Gwindows.List_Boxes.List_Box_Type(Obj.My_Peer.all),
            Item => I);
      end loop;
   end Delete_Entry;

   ------------------------------------------------
   -- Get_Item
   ------------------------------------------------
   function Get_Item(
      Obj : in Listbox;
      Number : in Natural) return String is
   begin
      return To_String(Gwindows.List_Boxes.Value (
         List => Gwindows.List_Boxes.List_Box_Type(Obj.My_Peer.all),
         Item => Number));
   end Get_Item;
   
   ------------------
   -- Get_Selected --
   ------------------

   function Get_Selected (Obj : in Listbox) return Natural is
   begin
      return Gwindows.List_Boxes.Current(
         List => Gwindows.List_Boxes.List_Box_Type(
            Obj.My_Peer.all));
   end Get_Selected;

   -----------------
   -- Select_Item --
   -----------------

   procedure Select_Item
     (Obj    : in out Listbox;
      Number : in     Natural)
   is
   begin
      Gwindows.List_Boxes.Current(
         List => Gwindows.List_Boxes.List_Box_Type(
            Obj.My_Peer.all),
         Item => Number);
   end Select_Item;

end Mcc.Gui.Widget.Listbox;

