-------------------------------------------------------------------
--           RAPID - RAPID ADA PORTABLE INTERFACE DESIGNER         
--           MCC GUI PACKAGE LIBRARY                               
--           Copyright (C) 1999 Martin C. Carlisle.                
--                                                                 
-- RAPID is free software;  you can  redistribute it  and/or modify
-- it under terms of the  GNU General Public License as published  
-- by the Free Software  Foundation;  either version 2,  or (at your
-- option) any later version.  RAPID is distributed in the hope that 
-- it will be useful, but WITHOUT ANY WARRANTY;  without even the 
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
-- PURPOSE.  See the GNU General Public License for more details.  
-- You should have  received  a copy of the GNU General Public License
-- distributed with RAPID; see file COPYING.  If not, write to the 
-- Free Software Foundation,  59 Temple Place - Suite 330,  Boston, 
-- MA 02111-1307, USA.                                                 
--                                                                     
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an 
-- executable, this unit does not by itself cause the resulting 
-- executable to be covered by the GNU General Public License.  
-- This exception does not however invalidate any other reasons 
-- why the executable file might be covered by the GNU Public 
-- License.  This exception does not apply to executables which
-- are GUI design tools, or that could act as a replacement
-- for RAPID.
------------------------------------------------------------------------------
with MSSyst.Windows;
use MSSyst.Windows;
with MSSyst.Windows.Forms;
use MSSyst.Windows.Forms;
with MSSyst.Windows.Forms.ListBox;
with MSSyst.Windows.Forms.ListBox.ObjectCollection;
with MSSyst.Windows.Forms.Control.ControlCollection;
with MSSyst.Object;
with Ada.Unchecked_Conversion;
with MSSyst.String;
use  MSSyst.String;

package body Mcc.Gui.Widget.Listbox is

   ---------------
   -- Add_Entry --
   ---------------

   procedure Add_Entry
     (Obj      : in out Listbox;
      Location : in     Natural;
      Text     : in     String)
   is
      The_Peer : Forms.ListBox.Ref := Forms.ListBox.Ref(Obj.My_Peer);
      Items    : access Forms.ListBox.ObjectCollection.Typ;
   begin
      Items := The_Peer.Get_Items;
      Items.Insert(Location,MSSyst.Object.Ref(+Text));
   end Add_Entry;

   -----------
   -- Clear --
   -----------

   procedure Clear (Obj  : in out Listbox) is
      The_Peer : Forms.ListBox.Ref := Forms.ListBox.Ref(Obj.My_Peer);
      Items    : access Forms.ListBox.ObjectCollection.Typ;
   begin
      Items := The_Peer.Get_Items;
      Items.Clear;
   end Clear;

   -----------
   -- Count --
   -----------

   function Count (Obj : in Listbox) return Natural is
      The_Peer : Forms.ListBox.Ref := Forms.ListBox.Ref(Obj.My_Peer);
      Items    : access Forms.ListBox.ObjectCollection.Typ;
   begin
      Items := The_Peer.Get_Items;
      return Items.get_Count;
   end Count;

   ------------
   -- Create --
   ------------

   procedure Create
     (Obj                  : in out Listbox;
      Parent               : in     Mcc.Gui.Container.Container'Class;
      X                    : in     Integer;
      Y                    : in     Integer;
      Width                : in     Natural;
      Height               : in     Natural;
      Horizontal_Scrollbar : in     Boolean;
      Vertical_Scrollbar   : in     Boolean)
   is
      The_Peer : MSSyst.Windows.Forms.ListBox.Ref;
      type Parent_Access is access constant Mcc.Gui.Container.Container'Class;
      function Convert is new Ada.Unchecked_Conversion(
         Parent_Access,Mcc.Gui.Container.Container_Pointer);
      Parent_Peer : Control.Ref := Control.Ref(
         Mcc.Gui.Container.Get_Peer(Parent));
      Collection : access Control.ControlCollection.Typ;
   begin
      The_Peer := MSSyst.Windows.Forms.ListBox.new_ListBox;
      -- ok, so it might seem odd to do this, but since we reuse 
      -- variables, it is important to renull these on create   
      Obj.Mouse_Handler := null;   
      Obj.Key_Handler := null;   
         
      Obj.My_Peer := MSSyst.Object.Ref(The_Peer);

      
      Collection := Parent_Peer.Get_Controls;
      Collection.add(Control.Ref(Obj.My_Peer));
      The_Peer.set_Top(y);
      The_Peer.set_Left(x);
      The_Peer.set_Height(Height);
      The_Peer.Set_Width(Width);
      The_Peer.Set_HorizontalScrollbar(Horizontal_Scrollbar);
      The_Peer.Set_ScrollAlwaysVisible(Vertical_Scrollbar);
      Obj.Parent := Convert(Parent'Unchecked_Access);
   end Create;

   ------------------
   -- Delete_Entry --
   ------------------

   procedure Delete_Entry
     (Obj   : in out Listbox;
      Start : in     Natural;
      Stop  : in     Natural)
   is
      The_Peer : Forms.ListBox.Ref := Forms.ListBox.Ref(Obj.My_Peer);
      Items    : access Forms.ListBox.ObjectCollection.Typ;
   begin
      Items := The_Peer.Get_Items;
      for I in Start-1..Stop-1 loop
         Items.RemoveAt(I);
      end loop;
   end Delete_Entry;

   ------------------
   -- Get_Selected --
   ------------------

   function Get_Selected (Obj : in Listbox) return Natural is
      The_Peer : Forms.ListBox.Ref := Forms.ListBox.Ref(Obj.My_Peer);
   begin
      return The_Peer.get_SelectedIndex+1;
   end Get_Selected;

   -----------------
   -- Select_Item --
   -----------------

   procedure Select_Item
     (Obj    : in out Listbox;
      Number : in     Natural)
   is
      The_Peer : Forms.ListBox.Ref := Forms.ListBox.Ref(Obj.My_Peer);
   begin
      The_Peer.set_SelectedIndex(Number-1);
   end Select_Item;

   function Get_Item(
         Obj : in Listbox;
         Number : in Natural) return String is
      The_Peer : Forms.ListBox.Ref := Forms.ListBox.Ref(Obj.My_Peer);
      Items    : access Forms.ListBox.ObjectCollection.Typ;
      Item     : MSSyst.Object.Ref;
   begin
      Items := The_Peer.Get_Items;
      Item := MSSyst.Object.Ref(Items.get_Item(Number-1));
      return +Item.ToString;
      
   end Get_Item;

end Mcc.Gui.Widget.Listbox;

