-------------------------------------------------------------------
--           RAPID - RAPID ADA PORTABLE INTERFACE DESIGNER         
--           MCC GUI PACKAGE LIBRARY                               
--           Copyright (C) 1999 Martin C. Carlisle.                
--                                                                 
-- RAPID is free software;  you can  redistribute it  and/or modify
-- it under terms of the  GNU General Public License as published  
-- by the Free Software  Foundation;  either version 2,  or (at your
-- option) any later version.  RAPID is distributed in the hope that 
-- it will be useful, but WITHOUT ANY WARRANTY;  without even the 
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
-- PURPOSE.  See the GNU General Public License for more details.  
-- You should have  received  a copy of the GNU General Public License
-- distributed with RAPID; see file COPYING.  If not, write to the 
-- Free Software Foundation,  59 Temple Place - Suite 330,  Boston, 
-- MA 02111-1307, USA.                                                 
--                                                                     
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an 
-- executable, this unit does not by itself cause the resulting 
-- executable to be covered by the GNU General Public License.  
-- This exception does not however invalidate any other reasons 
-- why the executable file might be covered by the GNU Public 
-- License.  This exception does not apply to executables which
-- are GUI design tools, or that could act as a replacement
-- for RAPID.
------------------------------------------------------------------------------
with Mcc.Gui.Widget.Peer;
with Gtk.Gentry;
with Gdk;
with Glib; use Glib;
with gdk.types; use gdk.types; with gtk.widget;
with Gtk.Enums; -- 20030424ph
package body Mcc.Gui.Widget.Text_Entry is

   -----------
   -- Clear --
   -----------

   procedure Clear (Obj  : in out Text_Entry) is
   begin
      gtk.gentry.Set_Text(The_Entry => gtk.gentry.gtk_entry(Obj.My_Peer),
                          Text      => "");
   end Clear;

   ------------
   -- Create --
   ------------

   procedure Create(Obj    : in out Text_Entry;
                    Parent : in     Mcc.Gui.Container.Container'Class;
                    X      : in     Integer;
                    Y      : in     Integer;
                    Width  : in     Natural;
                    Height : in     Natural)is
   New_Entry : gtk.gentry.Gtk_Entry;
   begin
      gtk.gentry.Gtk_New(Widget => New_Entry);
      
      --Have Object point to Entry Widget
      Obj.My_Peer := gtk.root_type_access(New_Entry);
      Gtk.Widget.Set_Events(
         Widget => Gtk.Widget.Gtk_Widget(New_Entry),
         Events => Gdk.Types.Button_Motion_Mask +
            Gdk.Types.Key_Release_Mask +
            Gdk.Types.Key_Press_Mask +
            Gdk.Types.Button_Press_Mask +
            Gdk.Types.Button_Release_Mask +
            Gdk.Types.Pointer_Motion_Mask
            );
     
      Mcc.Gui.Widget.Peer.Setup(
         Obj    => Obj,
         X      => X,
         Y      => Y,
         Width  => Width,
         Height => Height,
         Parent => Parent);
   end Create;

   procedure Disable(Obj : in out Text_Entry) is
   begin
      Gtk.Widget.Set_State(
         Gtk.Widget.Gtk_Widget(Obj.My_Peer),
         Gtk.Enums.State_Insensitive);
   end Disable;

   procedure Enable(Obj : in out Text_Entry) is
   begin
      Gtk.Widget.Set_State(
         Gtk.Widget.Gtk_Widget(Obj.My_Peer),
         Gtk.Enums.State_Normal);
   end Enable;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return String is
   begin
      return gtk.gentry.Get_Text(gtk.gentry.Gtk_Entry(Obj.My_Peer));
   end Get_Text;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return Integer is
   begin
      return Integer'Value(gtk.gentry.Get_Text(gtk.gentry.Gtk_Entry(Obj.My_Peer)));
   end Get_Text;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return Float is
   begin
      return Float'Value(gtk.gentry.Get_Text(gtk.gentry.Gtk_Entry(Obj.My_Peer)));
   end Get_Text;

   ---------------------
   -- Get_Text_Length --
   ---------------------

   function Get_Text_Length (Obj : in Text_Entry) return Natural is

   begin
      declare 
         Temp : String := Get_Text(Obj);
      begin
         return Temp'Length;
      end;
   end Get_Text_Length;

   ---------------
   -- Highlight --
   ---------------

   procedure Highlight (Obj : in out Text_Entry) is
   begin
      Highlight(Obj     => Obj,
                Start   => 0,
                Stop    => Get_Text_Length(Obj));
   end Highlight;

   ---------------
   -- Highlight --
   ---------------

   procedure Highlight(Obj   : in out Text_Entry;
                        Start : in     Natural;
                        Stop  : in     Natural) is
   begin--Highlight
      gtk.gentry.Select_Region(
         Editable => gtk.gentry.gtk_entry(Obj.My_Peer),
         Start     => Glib.Gint(Start),
         The_End   => Glib.Gint(Stop));
   end Highlight;

   --------------
   -- Set_Text --
   --------------

   procedure Set_Text(Obj  : in out Text_Entry;
                      Text : in     String)is
   begin
      gtk.gentry.Set_Text(The_Entry => gtk.gentry.gtk_entry(Obj.My_Peer),
                          Text      => text);
   end Set_Text;

   ------------------------------------------------
   -- procedure Set_Text
   --
   -- Set text for a text entry using
   -- image of integer (w/o leading spaces)
   ------------------------------------------------
   procedure Set_Text(
      Obj  : in out Text_Entry;
      Text : in     Integer) is
      -- return image of integer w/o leading space
      function integer_image(x : in integer) return String is
         result : string := integer'image(x);
      begin
         if result(result'first) = ' ' then
            return result(result'first+1..result'last);
         else
            return result;
         end if;
      end integer_image;
   begin
      Set_Text(Obj,Integer_Image(Text));
   end Set_Text;

end Mcc.Gui.Widget.Text_Entry;

