-------------------------------------------------------------------
--           RAPID - RAPID ADA PORTABLE INTERFACE DESIGNER         
--           MCC GUI PACKAGE LIBRARY                               
--           Copyright (C) 1999 Martin C. Carlisle.                
--                                                                 
-- RAPID is free software;  you can  redistribute it  and/or modify
-- it under terms of the  GNU General Public License as published  
-- by the Free Software  Foundation;  either version 2,  or (at your
-- option) any later version.  RAPID is distributed in the hope that 
-- it will be useful, but WITHOUT ANY WARRANTY;  without even the 
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
-- PURPOSE.  See the GNU General Public License for more details.  
-- You should have  received  a copy of the GNU General Public License
-- distributed with RAPID; see file COPYING.  If not, write to the 
-- Free Software Foundation,  59 Temple Place - Suite 330,  Boston, 
-- MA 02111-1307, USA.                                                 
--                                                                     
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an 
-- executable, this unit does not by itself cause the resulting 
-- executable to be covered by the GNU General Public License.  
-- This exception does not however invalidate any other reasons 
-- why the executable file might be covered by the GNU Public 
-- License.  This exception does not apply to executables which
-- are GUI design tools, or that could act as a replacement
-- for RAPID.
------------------------------------------------------------------------------
with Gwindows.Edit_Boxes;
with Gwindows.Base;
with Peer;
use Peer;
with Peer_To_Mcc;
package body Mcc.Gui.Widget.Text_Entry is

   -----------
   -- Clear --
   -----------

   procedure Clear (Obj  : in out Text_Entry) is
   begin
      Gwindows.Edit_Boxes.Clear(
         Gwindows.Edit_Boxes.Edit_Box_Type(Obj.My_Peer.all));
   end Clear;

   ------------
   -- Create --
   ------------

   procedure Create
     (Obj    : in out Text_Entry;
      Parent : in     Mcc.Gui.Container.Container'Class;
      X      : in     Integer;
      Y      : in     Integer;
      Width  : in     Natural;
      Height : in     Natural)
   is
      My_Peer : Gwindows.Edit_Boxes.Edit_Box_Access;
   begin
      My_Peer := new Gwindows.Edit_Boxes.Edit_Box_Type;
      Gwindows.Edit_Boxes.Create(
         Edit              => My_Peer.all,
         Parent            => Mcc.Gui.Container.Get_Peer(Parent).all,
         Text              => +"",
         Left              => X,
         Top               => Y,
         Width             => Width,
         Height            => Height,
         Horizontal_Scroll => False);
      Obj.My_Peer := Peer.Peer(My_Peer);
      Peer_To_Mcc.Hash_Package.Set(
         K => My_Peer.all'Address,
         E => Obj'Unrestricted_Access);
   end Create;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return String is
   begin
      return To_String (Gwindows.Base.Text(Obj.My_Peer.all));
   end Get_Text;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return Integer is
   begin
      return Integer'Value(
         To_String (Gwindows.Base.Text(Obj.My_Peer.all)));
   end Get_Text;

   --------------
   -- Get_Text --
   --------------

   function Get_Text (Obj : in Text_Entry) return Float is
   begin
      return Float'Value(
         To_String (Gwindows.Base.Text(Obj.My_Peer.all)));
   end Get_Text;

   ---------------------
   -- Get_Text_Length --
   ---------------------

   function Get_Text_Length (Obj : in Text_Entry) return Natural is
      Text_String : String := Get_Text(Obj);
   begin
      return Text_String'Length;
   end Get_Text_Length;

   ---------------
   -- Highlight --
   ---------------

   procedure Highlight (Obj : in out Text_Entry) is
   begin
      Gwindows.Edit_Boxes.Set_Selection(
         Edit           => 
            Gwindows.Edit_Boxes.Edit_Box_Type(Obj.My_Peer.all),
         Start_Position => 0,
         End_Position   => Get_Text_Length(Obj));
   end Highlight;

   ---------------
   -- Highlight --
   ---------------

   procedure Highlight
     (Obj   : in out Text_Entry;
      Start : in     Natural;
      Stop  : in     Natural)
   is
   begin
      Gwindows.Edit_Boxes.Set_Selection(
         Edit           => 
            Gwindows.Edit_Boxes.Edit_Box_Type(Obj.My_Peer.all),
         Start_Position => Start,
         End_Position   => Stop);
   end Highlight;

   --------------
   -- Set_Text --
   --------------

   procedure Set_Text
     (Obj  : in out Text_Entry;
      Text : in     String)
   is
   begin
      Gwindows.Base.Text(
         Window => Obj.My_Peer.all,
         Text   => +Text);
   end Set_Text;

   --------------
   -- Set_Text --
   --------------

   procedure Set_Text
     (Obj  : in out Text_Entry;
      Text : in     Integer)
   is
      Text_String : String := Integer'Image(Text);
   begin
      if Text < 0 then
         Set_Text(Obj,Text_String);
      else
         Set_Text(Obj,Text_String(Text_String'First+1..Text_String'Last));
      end if;
   end Set_Text;

end Mcc.Gui.Widget.Text_Entry;

